Récupérer sa clef Windows

[Edtech]

Pour récupérer la clef avec laquelle le système a été installé, il suffit de créer une fichier .bat avec le code suivant puis de l'exécuter :

::' Windows RT 8.0 Product Key Dumper by Myria of xda-developers.com
::' Original Windows 8.0 VBScript by janek2012 of mydigitallife.info
::' Batch+VBScript hybrid trick by dbenham of stackoverflow.com
::' Fix for keys starting with N by Osprey00 of xda-developers.com
::'
::' Windows RT doesn't let unsigned VBScript use WScript.Shell, which is
::' required in order to read the registry in VBScript.  So instead, we
::' have a batch file call reg.exe to do the registry lookup for us, then
::' execute the VBScript code.  Might as well do things this way, since
::' it would really suck to write this math in batch...

::' --- Batch portion ---------
rem^ &@echo off
rem^ &call :'sub
::' If we were run from double-clicking in Explorer, pause.
rem^ &if %0 == "%~0" pause
rem^ &exit /b 0

:'sub
::' Read the registry key into VBScript's stdin.
rem^ &("%SystemRoot%\System32\reg.exe" query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v DigitalProductId | cscript //nologo //e:vbscript "%~f0")
::'rem^ &echo end batch
rem^ &exit /b 0

'----- VBS portion ------------
'WScript.Echo "begin VBS"

' Get registry data that was piped in
RegData = ""
Do While Not WScript.StdIn.AtEndOfStream
    RegData = RegData & WScript.StdIn.ReadAll
Loop

' Remove any carriage returns
RegData = Replace(RegData, ChrW(13), "")

' Split into lines
RegLines = Split(RegData, ChrW(10))

' Sanity checking on data
If (RegLines(0) <> "") Or (RegLines(1) <> "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion") Then
    WScript.Echo "Got invalid header trying to run reg.exe"
    WScript.Quit(1)
End If

If Left(RegLines(2), 38) <> "    DigitalProductId    REG_BINARY    " Then
    WScript.Echo "Got invalid value list trying to run reg.exe"
    WScript.Quit(1)
End If

' Get hex string
HexString = Mid(RegLines(2), 39)
If (Len(HexString) Mod 2) <> 0 Then
    WScript.Echo "Got an odd number of hex digits in REG_BINARY data"
    WScript.Quit(1)
End If

' Convert to byte array
Dim ByteArray()
ReDim ByteArray((Len(HexString) / 2) - 1)  ' VBScript is just weird with array dimensions >.<

For i = 0 To (Len(HexString) - 2) Step 2
    ByteArray(i / 2) = CInt("&H" + Mid(HexString, i + 1, 2))
Next

Key = ConvertToKey(ByteArray)
WScript.Echo Key

' janek2012's magic decoding function
Function ConvertToKey(Key)
    Const KeyOffset = 52 ' Offset of the first byte of key in DigitalProductId - helps in loops
    isWin8 = (Key(66) \  And 1 ' Check if it's Windows 8 here...
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) ' Replace 66 byte with logical result
    Chars = "BCDFGHJKMPQRTVWXY2346789" ' Characters used in Windows key
    ' Standard Base24 decoding...
    For i = 24 To 0 Step -1
        Cur = 0
        For X = 14 To 0 Step -1
            Cur = Cur * 256
            Cur = Key(X + KeyOffset) + Cur
            Key(X + KeyOffset) = (Cur \ 24)
            Cur = Cur Mod 24
        Next
        KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
        Last = Cur
    Next
    ' If it's Windows 8, put "N" in the right place
    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Cur)
        insert = "N"
        KeyOutput = keypart1 & insert & Mid(KeyOutput, Cur + 2)
    End If
    ' Divide keys to 5-character parts
    a = Mid(KeyOutput, 1, 5)
    b = Mid(KeyOutput, 6, 5)
    c = Mid(KeyOutput, 11, 5)
    d = Mid(KeyOutput, 16, 5)
    e = Mid(KeyOutput, 21, 5)
    ' And join them again adding dashes
    ConvertToKey = a & "-" & b & "-" & c & "-" & d & "-" & e
    ' The result of this function is now the actual product key
End Function

[Gilbert_Gosseyn]

Pour récupérer la clef avec laquelle le système a été installé, il suffit de créer une fichier .bat avec le code suivant puis de l'exécuter :

Avec le code, c'est mieux .

[Edtech]

Je sais, juste que le formulaire chiait, je n'avais qu'un champ vide sans outils

 

Je vais reconstruire le cache du forum, la dernière mise à jour semble un peu foutre a merde...

[Gilbert_Gosseyn]

Je l'ai trouvé par ailleurs et confirme que ça marche très bien .

[Edtech]

Je l'ai trouvé par ailleurs et confirme que ça marche très bien .

 

Je l'ai ajouté ici car j'en ai marre de voir des gens télécharger des logiciels complets juste pour ça

[chaps]

Et quand on a Windows 10 via une mise à jour, c'est la même clé pour tout le monde ?

A savoir VK7JG-NPHTM-C97JM-9MPGT-3V66T ?

[Edtech]

Et quand on a Windows 10 via une mise à jour, c'est la même clé pour tout le monde ?

A savoir VK7JG-NPHTM-C97JM-9MPGT-3V66T ?

 

Je n'ai pas vérifié chez moi, il faudrait.

[Oliewan]

J'ai copié-collé le texte dans un fichier .txt, renommé en .bat et exécuté.

Le résultat obtenu est BBBBB-BBBBB-BBBBB-BBBBB

 

J'ai du mal à croire que ma clé soit celle-là...

[Strimy]

Je n'ai pas vérifié chez moi, il faudrait.

J'ai eu des comportements assez étranges. J'ai un appareil (une tablette en 32 bits) qui n'a pas cette clé suite à une mise à jour. Par contre, tous les autres (64 bits) ont bien cette clé après la mise à jour.

 

EDIT : My bad, j'ai cherché une partie de la clé de la tablette, et en fait ça correspond juste à la clé pour la version Home : YTMG3-N6DKC-DKB77-7M9GH-8HVX7

Modifié le 7 septembre 2015 par Strimy

[Soltek]

Et quand on a Windows 10 via une mise à jour, c'est la même clé pour tout le monde ?

A savoir VK7JG-NPHTM-C97JM-9MPGT-3V66T ?

 

Ouais au taff c'était une simple màj et j'ai cette clé. En perso avec une màj 7 > 10 puis clean install du 10 j'ai la même clé.

[Aloyse57]

Tous mes W10 ont maintenant cette clé -3V66T, même s'ils avaient tous une clé différente (et légale) sous Win7/8.1

[Edtech]

J'ai bien la clef générique pro : VK7JG-NPHTM-C97JM-9MPGT-3V66T

[chaps]

Idem, ce .bat me donne également VK7JG-NPHTM-C97JM-9MPGT-3V66T

[Oliewan]

? Je suis le seul avoir une clé foireuse ?

[chaps]

? Je suis le seul avoir une clé foireuse ?

 

Tu as testé sur quelle version de Windows ?

[Oliewan]

8.1 pro tout à jour.

[Edtech]

8.1 pro tout à jour.

 

J'utilise ce script sur mon Windows 8.1 RT (Surface 2) et j'ai bien la bonne clef qui remonte. Tu es sûr qu'il n'y a pas eu une erreur lorsque tu as créer ton .bat ?

Attention, sous 8.1, si le module DVD est installé, c'est cette clef qui remonte et plus celle de Windows (c'est bien con d'ailleurs !).

[Oliewan]

Tu entends quoi par "module DVD" ?

[Edtech]

L'extension pour Windows qui permet à Media Player de lire les DVD et qui installe Media Center. Comme il faut saisir une clef dans Windows, c'est cette nouvelle clef qui ressort et plus celle ayant servi à l'installation.

[digital-jedi]

En titre Edtech, tu pourrais mettre que ça ne concerne que W8.

[Edtech]

En titre Edtech, tu pourrais mettre que ça ne concerne que W8.

 

Bah non, parce que ça fonctionne pour Windows 10 aussi dans le cas où tu as acheté une version et pas mis à jour (PC neuf, Windows sur DVD neuf, etc.).

[Oliewan]

Bizarrement, après avoir fait relire le script par un collègue plus pointu, il apparait que le script fonctionne avec une table SLIC ancienne.

Testé sous Win7 pro : ca marche. Avec notre clé en volume licensing et une table SLIC en 2.1 ca marche pas.

[Gilbert_Gosseyn]

En titre Edtech, tu pourrais mettre que ça ne concerne que W8.

Non, ça fonctionne aussi sous Windows 7 Pro 64b.

[Alexandraminci]

Ou sinon tu télécharges PRODUCTKEY c'est gratuit... tout en souplesse :)

[brice.wernet]

Je confirme que pour le moment je n'ai pas réussi à récupérer de clé valable sous Windows 10. Ca renvoie toujours la même quelque soit l'ordi.

Si on ne change rien à un ordinateur, quand on réinstalle Windows 10 il s'active automatiquement lorsqu'il se connecte à internet. Si on fait un modif matérielle, il faut lui redonner la clé du dernier Windows installé (moi j'ai 7 puis 8 puis 10 sur ma machine, il faut que je lui donne la clé du 8 même après un fresh install lors d'un changement de carte mère)