[RESOLU] Petit programme de gestion de temps

[snooky]

Bonjour,

une demande ou une piste, concernant un programme ( sous windows ) à créer .

Il s'agit de la gestion de plusieurs billards en location :

Date et heure

Numéro de table

Heure de début

Heure de fin

Temps passé

Prix en ¤

Sortie d'un ticket sur imprimante avec ces infos.

J'ai actuellement de type de programme en QuickBasic sur floppy disk qui fonctionne sur un ordi qui date de la guerre...

J'aimerais donc faire tourner ce programme sous Windows 7 via Excel, un navigateur ou quelconque autre environnement.

Merci pour vos infos.

PS: évidemment, je n'y connais rien en programmation.

[Pinkpony]

T'as pas une salle de billard à côté de chez toi pour aller leur demander ? Je sais que la mienne a exactement ça.

[Tezca]

Bonjour,

Cela dépend des fonctionnalités que tu souhaites.

Doit-on pouvoir par exemple conserver un historique des locations ou est-ce une simple facture à imprimer puis basta ?

Faut-il prévoir le fait d'avoir plusieurs PC un jour ou n'y aura-t-il toujours qu'un PC qui l'utilise ?

Si ton utilisation est mono poste et sans base de données, y'a pas grand chose à faire.

Pourquoi tout simplement ne pas utiliser un modèle Word que tu complètes pour chaque client ?

[snooky]

Salut,

une simple facture à imprimer et à donner au client. ( le ticket de caisse fait la taille d'une carte bancaire )

PC unique ( placé au niveau de la caisse )

C'est la gestion du temps passé sur la table de billard ( puis convertit en € ) qui m'intéresse.

Merci pour ta réponse.

[snooky]

Sur l'écran , actuellement , j'ai ceci : ( il y a 22 tables )

Table 1 ( snooker ) * Début : XXXX * Fin: XXXX * Durée : XXhXXmn * Total : XXXX €

Table 2 ( snooker ) * Début : XXXX * Fin: XXXX * Durée : XXhXXmn * Total : XXXX €

etc ....

Je peux modifier :

l'heure et la date

le nombre et le type de tables

le tarif ( tarif client et tarif licencié )

O pour démarrer le compteur

N pour stopper le compteur ( et imprimer le ticket de caisse )

Je démarre donc le compteur d'une table via le clavier numérique , puis une fois leur partie terminée, il me suffit de cliquer sur le numéro de leur table, puis sur N pour que le compteur s'arrête ... le ticket s'imprime.

[Tezca]

Je vois 2 possibilités sympa :

- Feuille Excel customisée (simple mais artisanal et plus dur à maintenir)

- Petite appli WPF (plus costaud, plus adaptable mais plus complexe à coder)

A vue de nez compte 2 jours pour la solution 1 et 4j pour la 2.

[snooky]

Quel programme utiliser pour WPF ? Visual Studio ?

Tu pourrais me donner un exemple ou marche à suivre ?

Ceci est joli, mais ce n'est pas ce qu'il me faut ^^ ... quoique !

[treflemard]

Salut,

le compteur est obligatoire ? parce que si tu as l'heure de début et l'heure de fin tu n'as plus qu'à faire une soustraction.

Pour chaque table tu pourrais avoir

un bouton début ( qui inscrit automatiquement l'heure de début quand tu cliques )

un bouton fin ( qui inscrit automatiquement l'heure de fin quand tu cliques )

+ une case a cocher

tarif normal

tarif licencié.

Après si tun'as aucune connaissance en programmation, il va falloir soit apprendre un peu soit demander à qq'un de le faire.

[snooky]

Avec Excel, donc ?

[Tezca]

Oui WPF c'est avec Visual Studio.

De mémoire la version gratuite devrait suffire, à vérifier la licence d'exploitation d'un point de vue professionnel.

Par contre tu vas bien galérer en partant de zéro.

Il y a beaucoup de concepts à assimiler en WPF.

Je te conseille plutôt la méthode Excel si tu te lances toi même

[snooky]

Je vais donc me diriger vers la solution Excel ... une piste pour démarrer ?

Merci encore de t’intéresser à mon problème.

[snooky]

L'idée est de n’utiliser que le pavé numérique et quelques touches du clavier ... à la souris, c'est beaucoup plus gênant.

[Tezca]

Tu auras besoin de formules (pour les calculs) et certainement de macro pour l'impression.

Cherche des tutoriaux sympa au sujet d'Excel (part depuis le début), et dans tous les cas, comme le dit treflemard, ne t'attend pas à avoir fini demain

[green68]

Salut snooky,

Pour confirmation, ton prog fonctionne sous GW !

[green68]

Voici le listing GW de ton prog (enfin la version dont je dispose) :

5 LPRINT CHR$(27)+CHR$(71)+ CHR$(49)

6 LPRINT CHR$(27)+CHR$(114)+CHR$(48)

7 LPRINT CHR$(27)+CHR$(33)

10 SCREEN 0

20 COLOR 3,0,4

30 KEY OFF

40 REM ***** INITIALISATION DU TABLEAU

50 NBTABLE=38

60 DIM TABLE(38,2)

70 FOR X=1 TO NBTABLE

80 TABLE(X,1)=-1

90 TABLE(X,2)=-1

100 NEXT X

110 OPEN "sauve.dat" FOR INPUT AS #1

120 FOR I=1 TO 38

130 IF EOF(1) THEN GOTO 160

140 INPUT #1,TABLE(I,0),TABLE(I,1),TABLE(I,2)

150 NEXT I

160 CLOSE#1

170 OPEN "ws.tar" FOR INPUT AS #1

180 INPUT #1,WS

190 CLOSE#1

200 IF WS=1 THEN WS$="semaine" ELSE WS$="week-end"

210 REM ***** PRESENTATION

220 CLS

230 LOCATE 11,1

240 PRINT " Logiciel de gestion de temps de fonctionnement des tables de billard du Holiday Club"

250 LOCATE 23,78:INPUT "",A

260 CLS

270 REM ***** MENU 1

280 ON ERROR GOTO 3090

290 Z$=""

300 GOTO 680

310 LOCATE 23,5

320 PRINT "M- Menu Q- Quitter Tarif:";WS$

330 REM ***** CHOIX MENU 1

340 IF Z$<>CHR$(13) THEN 440 ELSE Z$=""

350 IF (VAL(M$)>0 AND VAL(M$)<39) THEN NUMTABLE=VAL(M$):GOSUB 470:M$=""

360 IF (M$="m" OR M$="M") THEN GOSUB 1770:M$=""

370 IF M$<>"q" AND M$<>"Q" THEN 430

380 LOCATE 23,1:PRINT SPACE$(80);

390 LOCATE 23,32:COLOR 14,4:PRINT "Quitter (O/N) ?"

400 Q$=INKEY$:IF Q$="" THEN 400

405 IF Q$="y" OR Q$="Y" THEN SYSTEM

410 IF Q$<>"o" AND Q$<>"O" THEN LOCATE 23,32:COLOR 7,0:PRINT SPACE$(15):GOTO 430

420 CLS:OPEN "sauve.dat" FOR OUTPUT AS #1:FOR I=1 TO 38:WRITE#1,TABLE(I,0),-1,-1:NEXT I:CLOSE#1:SYSTEM

430 IF (VAL(M$)<1 OR VAL(M$)>38) THEN M$=""

440 IF LEN(M$)=2 THEN M$=""

450 M$=M$+Z$:Z$="":LOCATE 23,1:PRINT " ":LOCATE 23,1:PRINT M$

460 GOTO 720

470 REM ***** DEMARRAGE TABLE

480 A=VAL(M$)

490 IF A=0 THEN 270

500 IF TABLE(A,1)<>-1 AND TABLE(A,2)=-1 THEN 560

510 GOSUB 1500

520 TABLE(A,1)=B

530 TABLE(A,2)=-1

540 OPEN "sauve.dat" FOR OUTPUT AS #1:FOR I=1 TO 38:WRITE#1,TABLE(I,0),TABLE(I,1),TABLE(I,2):NEXT I:CLOSE#1

550 RETURN

560 REM ***** ARRET TABLE

570 IF TABLE(A,0)=0 THEN 670

580 LOCATE 23,32:COLOR 14,4:PRINT "Arrˆter (O/N) ?"

590 Q$=INKEY$:IF Q$="" THEN 590

595 IF Q$="y" OR Q$="Y" THEN Q$="Y":GOTO 610

600 IF Q$<>"o" AND Q$<>"O" THEN Q$="N":LOCATE 23,32:COLOR 7,0:PRINT SPACE$(15):GOTO 670

610 LOCATE 22,1:PRINT SPACE$(80);

620 GOSUB 1500

630 GOSUB 900

640 GOSUB 1500

650 TABLE(A,2)=B

660 OPEN "sauve.dat" FOR OUTPUT AS #1:FOR I=1 TO 38:WRITE#1,TABLE(I,0),TABLE(I,1),TABLE(I,2):NEXT I:CLOSE#1

670 COLOR 3,0:IF Q$<>"Y" AND Q$<>"N" THEN GOSUB 2920

675 RETURN

680 REM ***** VISUALISATION DES TABLES

690 LOCATE 1,1: PRINT "Table Nø":LOCATE 1,11:PRINT"D‚part":LOCATE 1,21:PRINT"Fin":LOCATE 1,31:PRINT"Dur‚e"

700 IF NBTABLE<20 THEN 720

710 LOCATE 1,41: PRINT "Table Nø":LOCATE 1,51:PRINT"D‚part":LOCATE 1,61:PRINT"Fin":LOCATE 1,71:PRINT"Dur‚e"

720 LOCATE 23,5

730 PRINT "M- Menu Q- Quitter Tarif:";WS$

735 IF NUMTABLE<>0 THEN DEBUT=NUMTABLE:NUMTABLE=0 ELSE DEBUT=1

740 FOR X=DEBUT TO NBTABLE

750 Z$=INKEY$

760 IF Z$<>"" THEN 870

770 IF X<20 THEN GOSUB 880 ELSE GOSUB 890

780 IF TABLE(X,0)=0 THEN COLOR 0,0

790 IF TABLE(X,0)=1 THEN IF TABLE(X,1)<>-1 AND TABLE(X,2)=-1 THEN COLOR 15,2 ELSE COLOR 0,2

800 IF TABLE(X,0)=2 THEN IF TABLE(X,1)<>-1 AND TABLE(X,2)=-1 THEN COLOR 15,3 ELSE COLOR 0,3

810 IF TABLE(X,0)=3 THEN IF TABLE(X,1)<>-1 AND TABLE(X,2)=-1 THEN COLOR 15,6 ELSE COLOR 0,6

820 LOCATE Y,D:PRINT" ";:PRINT USING"##";X;:PRINT" ";:GOSUB 1530:PRINT USING"\ \";A$;:PRINT" ";:GOSUB 1590:PRINT USING "\ \";B$;:PRINT" ";:GOSUB 1650:PRINT USING"\ \";C$;

830 COLOR 3,0

835 LOCATE 23,70:PRINT MID$(DATE$,4,3)+LEFT$(DATE$,3)+RIGHT$(DATE$,4);

840 LOCATE 24,71: PRINT TIME$;

850 NEXT X

860 GOTO 735

870 GOTO 310

880 Y=X+2:D=1:RETURN

890 Y=X+2-19:D=41:RETURN

900 REM ***** CALCUL ADDITION

910 IF TABLE(A,0)>1 THEN 1400

920 IF WS$="semaine" THEN GOTO 1030 ELSE GOTO 1110

930 LOCATE 22,1:PRINT SPACE$(80);

940 LOCATE 22,1:PRINT "Table Nø";A;" Plein :";:PRINT USING " ####.00";TOTAL1;:PRINT" Frs"

950 IF WS$="semaine" THEN GOTO 1180 ELSE GOTO 1260

960 LOCATE 22,34:PRINT "Adh‚rent :";:PRINT USING" ####.00";TOTAL2;:PRINT" Frs"

970 GOTO 1330

980 LOCATE 22,58:PRINT "Licenci‚ :";:PRINT USING" ####.00";TOTAL3;:PRINT" Frs"

990 REM LOCATE 23,1:INPUT "",AZER

1000 REM LOCATE 23,1:PRINT" "

1010 REM ***** RENVOI VERS IMPRIMANTE

1020 RETURN

1030 OPEN "plein1.tar" FOR INPUT AS #1

1040 INPUT #1,COEF

1050 CLOSE#1

1060 COEFF=COEF/60

1070 TOTAL1=(B-TABLE(A,1))*COEFF:LOCATE 22,1:PRINT TOTAL1

1080 IF TOTAL1<0 THEN TOTAL1=((1440-TABLE(A,1))+B)*COEFF

1090 LOCATE 22,20:PRINT TOTAL1

1100 GOTO 940

1110 OPEN"PLEIN2.tar" FOR INPUT AS #1

1120 INPUT #1,COEF

1130 CLOSE#1

1140 COEFF=COEF/60

1150 TOTAL1=(B-TABLE(A,1))*COEFF

1160 IF TOTAL1<0 THEN TOTAL1=((1440-TABLE(A,1))+B)*COEFF

1170 GOTO 940

1180 OPEN"adher1.tar" FOR INPUT AS #1

1190 INPUT #1,COEF

1200 COEFF=COEF/60

1210 COEFF=COEF/60

1220 TOTAL2=(B-TABLE(A,1))*COEFF

1230 IF TOTAL2<0 THEN TOTAL2=((1440-TABLE(A,1))+B)*COEFF

1240 CLOSE#1

1250 GOTO 960

1260 OPEN"adher2.tar" FOR INPUT AS #1

1270 INPUT #1,COEF

1280 CLOSE#1

1290 COEFF=COEF/60

1300 TOTAL2=(B-TABLE(A,1))*COEFF

1310 IF TOTAL2<0 THEN TOTAL2=((1440-TABLE(A,1))+B)*COEFF

1320 GOTO 960

1330 OPEN"licen.tar" FOR INPUT AS #1

1340 INPUT #1,COEF

1350 CLOSE#1

1360 COEFF=COEF/60

1370 TOTAL3=(B-TABLE(A,1))*COEFF

1380 IF TOTAL3<0 THEN TOTAL3=((1440-TABLE(A,1))+B)*COEFF

1390 GOTO 980

1400 OPEN"pool.tar" FOR INPUT AS #1

1410 INPUT #1,COEF

1420 CLOSE#1

1430 COEFF=COEF/60

1440 TOTAL4=(B-TABLE(A,1))*COEFF

1450 IF TOTAL4<0 THEN TOTAL4=((1440-TABLE(A,1))+B)*COEFF

1460 LOCATE 22,1:PRINT " "

1470 LOCATE 22,1: PRINT "Table Nø: ";A;" Tarif :";:PRINT USING " ####.00";TOTAL4;:PRINT" Frs"

1480 REM LOCATE 23,1:INPUT "",AZER

1490 RETURN

1500 REM ***** CALCUL DE L'HEURE EN MINUTES

1510 B=VAL(MID$(TIME$,1,2))*60+VAL(MID$(TIME$,4,2))

1520 RETURN

1530 REM ***** ECRITURE HEURE DE DEBUT

1540 IF TABLE(X,1)=-1 THEN A$="":RETURN

1550 A=INT(TABLE(X,1)/60)

1560 B=TABLE(X,1)-(A*60)

1570 GOSUB 1761:A$=T1$

1580 RETURN

1590 REM ***** ECRITURE HEURE DE FIN

1600 IF TABLE(X,2)=-1 THEN B$=" ":RETURN

1610 A=INT(TABLE(X,2)/60)

1620 B=TABLE(X,2)-(A*60)

1630 GOSUB 1761:B$=T1$

1640 RETURN

1650 REM ***** CALCUL DUREE DE FONCTIONNEMENT

1660 IF TABLE(X,1)=-1 THEN C$=" ":RETURN

1670 IF TABLE(X,2)<>-1 THEN B=TABLE(X,2):GOTO 1690

1680 GOSUB 1500

1690 IF B>TABLE(X,1) THEN 1710

1700 B=1440+B

1710 E=B-TABLE(X,1)

1720 IF E=1440 THEN C$="00:00 ":RETURN

1730 A=INT(E/60)

1740 B=E-(INT(E/60)*60)

1750 GOSUB 1761:C$=T1$

1760 RETURN

1761 REM ***** FORMATE HEURE:MINUTES

1762 T1$=STR$(A):IF LEN(T1$)=2 THEN T1$="0"+RIGHT$(T1$,1) ELSE T1$=RIGHT$(T1$,2)

1763 T2$=STR$(B):IF LEN(T2$)=2 THEN T2$="0"+RIGHT$(T2$,1) ELSE T2$=RIGHT$(T2$,2)

1764 T1$=T1$+":"+T2$

1769 RETURN

1770 REM ***** MENU 2

1780 CLS

1790 LOCATE 1,20:PRINT" MENU PRINCIPAL"

1800 LOCATE 2,20:PRINT" ---- ---------"

1810 LOCATE 10,10:PRINT"1- Fichier client"

1820 LOCATE 11,10:PRINT"2- Tarifs"

1830 LOCATE 12,10:PRINT"3- R‚glage heure"

1840 LOCATE 13,10:PRINT"4- Types des tables"

1850 LOCATE 15,10:PRINT"5- Retour"

1860 MENU2$=INKEY$

1870 IF MENU2$="1" THEN GOSUB 1770

1880 IF MENU2$="2" THEN GOSUB 2030

1890 IF MENU2$="3" THEN GOSUB 2450

1900 IF MENU2$="4" THEN GOSUB 2610

1910 IF MENU2$="5" THEN GOTO 2550

1920 GOTO 1790

1930 REM ***** NOMBRE DE TABLES

1940 CLS

1950 LOCATE 1,20:PRINT "NOMBRE DE TABLES TOTAL"

1960 LOCATE 2,20:PRINT "------ -- ------ -----"

1970 LOCATE 10,10:PRINT "Actuel : ";NBTABLE;" Tables"

1980 LOCATE 11,10: INPUT "Nouveau : ",NB

1990 IF NB=0 THEN 2010

2000 NBTABLE=NB

2010 CLS

2020 RETURN

2030 REM ***** REGLAGE TARIFS

2040 CLS

2050 LOCATE 1,20:PRINT"REGLAGE DES TARIFS"

2060 LOCATE 2,20:PRINT"------- --- ------"

2070 LOCATE 3,10:PRINT "1- Plein"

2080 LOCATE 4,10:PRINT "2- Adh‚rent"

2090 LOCATE 5,10:PRINT "3- Licenci‚"

2100 LOCATE 8,10:PRINT "5- Week-end / Semaine";

2110 OPEN "ws.tar" FOR INPUT AS #1

2120 INPUT #1,WS

2130 IF WS=1 THEN WS$="semaine" ELSE WS$="week-end"

2140 PRINT " ( Actuel: ";WS$;") "

2150 CLOSE #1

2160 LOCATE 6,10:PRINT "4- Pool / Am‚ricain"

2170 LOCATE 10,10: PRINT "Tarif … modifier :"

2180 T$=INKEY$:IF T$="" THEN 2180

2190 T=VAL(T$)

2200 IF T=0 THEN CLS:RETURN

2210 IF T<0 OR T>5 THEN 2170

2220 IF T=1 AND WS=1 THEN T$="plein1":GOTO 2310

2230 IF T=1 AND WS=2 THEN T$="plein2":GOTO 2310

2240 IF T=3 THEN T$="licen":GOTO 2310

2250 IF T=2 AND WS=1 THEN T$="adher1":GOTO 2310

2260 IF T=2 AND WS=2 THEN T$="adher2":GOTO 2310

2270 IF T=3 THEN T$="licen":GOTO 2310

2280 IF T=5 THEN GOTO 2400

2290 IF T=4 THEN T$="pool":GOTO 2310

2300 GOTO 2170

2310 OPEN T$+".tar" FOR INPUT AS #1:INPUT#1,Z

2320 LOCATE 12,10: PRINT "Actuel : ";Z:ANC=Z

2330 CLOSE#1

2340 OPEN T$+".tar" FOR OUTPUT AS #1

2350 LOCATE 13,10: INPUT "Nouveau : ",N

2360 IF N=0 THEN N=ANC

2370 WRITE#1,N

2380 CLOSE #1

2390 GOTO 2030

2400 OPEN "ws.tar" FOR OUTPUT AS #1

2410 IF WS$="semaine" THEN WRITE #1,2

2420 IF WS$="week-end" THEN WRITE #1,1

2430 CLOSE#1

2440 GOTO 2050

2450 REM ***** REGLAGE DE L'HEURE

2460 CLS

2470 LOCATE 1,20:PRINT "REGLAGE DE L'HEURE"

2480 LOCATE 2,20:PRINT "------- -- - -----"

2490 LOCATE 10,10:PRINT "Actuel : ";TIME$

2500 LOCATE 11,10: INPUT "Nouveau (00:00) : ",NH$

2510 IF NH$="" THEN 2530

2520 TIME$=NH$

2530 CLS

2540 RETURN

2550 REM ***** RETOUR MENU 1

2560 CLS

2570 LOCATE 1,1: PRINT "Table Nø":LOCATE 1,11:PRINT"D‚part":LOCATE 1,21:PRINT"Fin":LOCATE 1,31:PRINT"Dur‚e"

2580 IF NBTABLE<20 THEN 2600

2590 LOCATE 1,41: PRINT "Table Nø":LOCATE 1,51:PRINT"D‚part":LOCATE 1,61:PRINT"Fin":LOCATE 1,71:PRINT"Dur‚e"

2600 RETURN

2610 REM ***** REGLAGE TYPE DE TABLE

2620 CLS

2630 LOCATE 1,20: PRINT "REGLAGE DES TYPES DE TABLES"

2640 LOCATE 2,20: PRINT "------- --- ----- -- ------"

2650 LOCATE 10,10:INPUT " Table Nø :",T$

2660 IF T$="" THEN CLS:RETURN

2670 IF VAL(T$)<0 OR VAL(T$)>38 THEN 2610

2680 T=VAL(T$)

2690 LOCATE 12,10: PRINT "Actuel :";TABLE(T,0)

2700 LOCATE 12,40: PRINT "1- Snooker"

2710 LOCATE 13,40: PRINT "2- Am‚ricain"

2720 LOCATE 14,40: PRINT "3- Pool"

2730 LOCATE 13,10: INPUT "Nouveau: ",N

2740 IF N=0 THEN GOTO 2790

2750 IF N=1 THEN GOTO 2790

2760 IF N=2 THEN GOTO 2790

2770 IF N=3 THEN GOTO 2790

2780 GOTO 2730

2790 TABLE(T,0)=N:N=0

2800 OPEN"sauve.dat" FOR OUTPUT AS #1: FOR I=1 TO 38: WRITE #1,TABLE(I,0),TABLE(I,1),TABLE(I,2):NEXT I: CLOSE#1

2810 GOTO 2610

2920 REM ***** IMPRESSION TICKET *****

2921 X=A

2930 GOSUB 3120

2940 GOSUB 1530

2950 GOSUB 1590

2955 B=TABLE(X,2)

2960 GOSUB 1690

2970 IF TABLE(X,0)=1 THEN TYPE$="Snooker"

2980 IF TABLE(X,0)=2 THEN TYPE$="Am‚ricain"

2990 IF TABLE(X,0)=3 THEN TYPE$=" ~8~ Pool"

3000 LPRINT " H O L I D A Y C L U B ";JOUR$;" ";MOIS$;" ";ANNEE$

3010 LPRINT

3020 LPRINT "Table Nø";X;" : ";TYPE$

3030 LPRINT:LPRINT"DEBUT : ";:LPRINT A$;:LPRINT TAB(20)"Dur‚e : ";C$

3060 LPRINT"FIN : ";:LPRINT B$;

3070 GOSUB 3300

3075 LPRINT:LPRINT:LPRINT:LPRINT:LPRINT:LPRINT:LPRINT:LPRINT

3080 RETURN

3090 REM ***** GESTION MACHINE HORS TENSION

3091 IF ERR=27 THEN 3100

3092 RESUME 3080

3100 LOCATE 23,1:PRINT" IMPRIMANTE HORS TENSION"

3110 RESUME 3080

3120 REM ***** GESTION DATE

3130 JOUR$=MID$(DATE$,4,2)

3140 MOIS$=MID$(DATE$,1,2)

3150 ANNEE$=MID$(DATE$,7,4)

3160 MOIS=VAL(MOIS$)

3170 IF MOIS=1 THEN MOIS$="Jan"

3180 IF MOIS=2 THEN MOIS$="F‚v"

3190 IF MOIS=3 THEN MOIS$="Mar"

3200 IF MOIS=4 THEN MOIS$="Avr"

3210 IF MOIS=5 THEN MOIS$="Mai"

3220 IF MOIS=6 THEN MOIS$="Juin"

3230 IF MOIS=7 THEN MOIS$="Jul"

3240 IF MOIS=8 THEN MOIS$="Ao–t"

3250 IF MOIS=9 THEN MOIS$="Sep"

3260 IF MOIS=10 THEN MOIS$="Oct"

3270 IF MOIS=11 THEN MOIS$="Nov"

3280 IF MOIS=12 THEN MOIS$="D‚c"

3290 RETURN

3300 LPRINT:LPRINT CHR$(27)+CHR$(114)+CHR$(48)+"";

3301 LPRINT CHR$(27)+CHR$(33)+CHR$(49)

3302 IF TABLE(X,0)<>1 THEN 3321

3305 IF TOTAL1<>INT(TOTAL1) THEN TOTAL1=INT(TOTAL1)+1

3310 LPRINT"Billard :";:LPRINT INT(TOTAL1);:LPRINT" FF":GOTO 3335

3321 IF TOTAL4<>INT(TOTAL4) THEN TOTAL4=INT(TOTAL4)+1

3330 LPRINT"Billard :";:LPRINT INT(TOTAL4);:LPRINT" FF"

3335 LPRINT CHR$(27)+CHR$(114)+CHR$(48)

3336 LPRINT CHR$(27)+CHR$(33)

3340 RETURN

[green68]

Une visu du prog :

[snooky]

Thanks Green68 !

Vais essayer en copiant simplement ce programme sous windows .

[snooky]

Bon alors voilà... plutôt de créer un nouveau programme, l'actuel est tout à fait suffisant.

Mon souci actuel est de copier le programme sur une clé USB.

Le programme peut être copié uniquement sur une disquette formatée en 720Ko .

Or, mon lecteur de disquette refuse d'ouvrir la disquette de 720 Ko !!!

Question : comment passer de cette disquette à une clé USB ?

[snooky]

Bon, du neuf ...

Sur mon pc récent, j'ai réussi à formater une disquette en 720 Ko ( format a: /F:720 )

Reste plus qu'à vérifier si cette disquette est reconnue par mon vieux pc ...

[snooky]

Arf ... marche pas

" Disquette non reconnue "

L'explorateur mouline ...

le pc me propose de " formater la disquette " !

Une idée ?

Données à récupérées sur un Amstrad PC 2086 640K ( v1.4 )

[treflemard]

Salut,

tu l'as formaté en quoi ?

ton ancien pc connait ce système de fichiers ?

[snooky]

format a: /F:720

J'imagine que c'est du Fat...

J'ai alors pris cette disquette, puis copié les fichiers de mon Amstrad PC 2086 640K ( v1.4 )

Copie effectuée correctement.

En remettant cette disquette sur mon pc Seven :

" Disquette non reconnue "

L'explorateur mouline ...

Seven me propose de " formater la disquette " !

PS: Sur le Amstrad, je ne peux que formater en 720 Ko ( /F:720 )

[snooky]

Copie des fichiers ok via cmd dans Exécuter.

:)

[green68]

Visu de l'avancement programmation Java .exe installation Windows